REM -- ANYTIME YOU JSR 1100 YOU THEN GOTO 300:  IF NOT GOTO 1095


0 REM -- NASPITE IDIOT COMPILER PARSER VERSION 3.00  - 7.3.2018
1  HIMEM:25000
2  DIM CC$(150): DIM ZA$(150):LK = 16
5  PRINT  CHR$ (4);"PR#3": HOME:GOTO 800


REM ------------------- CREATE CODE FOR LINE (APPEND)
REM 300 ADD COMMAND,KEEP GOING - 325 ADD COMMAND, END LINE
300  PRINT : GOSUB 301:GOTO 1005
301  PRINT  CHR$ (4);"APPEND";ZA$: PRINT  CHR$ (4);"WRITE";ZA$
302  FOR X = 1 TO A: PRINT CC$(X): NEXT : PRINT  CHR$ (4);"CLOSE"
303  FOR X = 1 TO A: HTAB 50: PRINT CC$(X): NEXT : RETURN  

REM---------------------END LINE/CREATE CODE FOR LAST INSTRUCTION
325 IF A>0 THEN GOSUB 301
326 GOSUB 350:KP=LEN(ZA$)
327 GOTO 330

REM--------------------PRINT LISTING OF FINISHED LINE
330 A = 1:ZA$(1)="": ONERR  GOTO 333
331  PRINT  CHR$ (4);"OPEN";ZA$: PRINT  CHR$ (4);"READ";ZA$
332  INPUT ZA$(A):A = A + 1: GOTO 332

333  CALL -3288:PRINT  CHR$ (4);"CLOSE";ZA$
334  IF LEN(ZA$(1))=0 THEN A$="CANCEL":STOP:GOTO 1010
335  PRINT:PRINT ZA$: FOR B = 1 TO A-1: HTAB 5: PRINT ZA$(B): NEXT :GOTO 805


REM----------------ADD TO NEW COMPILED.LINES WITH CHECK FOR PRE-EXISTING
350  ONERR  GOTO 355
351  PRINT  CHR$ (4);"OPEN COMPILED.LINES"
352  PRINT  CHR$ (4);"READ COMPILED.LINES": INPUT GW$: PRINT  CHR$ (4)
353  IF GW$ = ZA$ THEN PRINT  CHR$ (4);"CLOSE COMPILED.LINES": RETURN 
354  GOTO 352

355  PRINT  CHR$ (4);"CLOSE COMPILED.LINES"
356  PRINT  CHR$ (4);"APPEND COMPILED.LINES"
357  PRINT  CHR$ (4);"WRITE COMPILED.LINES":PRINT ZA$
358  PRINT  CHR$ (4);"CLOSE COMPILED.LINES"
359  CALL -3288: RETURN


REM-------------------- NEW INPUT
400  T = 0:L =  LEN (SS$): IF L=0 THEN STOP:POP:STOP:GOTO 1000	
401  V=VAL(SS$):IF SS$ = "0" THEN GOTO 403 
402  IF V = 0 THEN II$ = SS$: GOSUB 500: RETURN 
403  T=1:RETURN


REM---------------------READ VARIABLE FILES
500  ONERR  GOTO 510
501  PRINT  CHR$ (4);"OPEN VARIABLES"
502  PRINT  CHR$ (4);"READ VARIABLES"
503  INPUT IJ$:IF II$ = IJ$ GOTO 505
504  GOTO 502
505 INPUT IX:IY = IX + 1:IZ = IY + 1: PRINT  CHR$ (4);"CLOSE": RETURN

510 PRINT  CHR$ (4);"CLOSE"
511 PRINT : PRINT "**CREATED NEW VARIABLE: ";II$:II =  VAL (IJ$):II = II + 3
512 PRINT  CHR$ (4);"APPEND VARIABLES": PRINT  CHR$ (4);"WRITE VARIABLES"
513 PRINT II$: PRINT II: PRINT  CHR$ (4);"CLOSE":CALL  - 3288:GOTO 501


REM----------------HEX CONVERSION
REM----------------TURN # INTO HEX DIGITS - INPUT H
700 HX(1) =  INT (H / 256):HX(2) = H - (HX(1) * 256): RETURN


800  PRINT  CHR$ (4);"BLOAD EXPORT.APP,A35000":LP = 35003
805 IF PEEK(LP-1)=0 THEN PRINT: PRINT "CONVERSION COMPLETE":PRINT "REBOOT COMPILER DISK...":END
807 LN=PEEK(LP)+PEEK(LP+1)*256:LP=LP+2:A$=STR$(LN)

810 ONERR GOTO 813
811 ZA$ = "LINE." + A$
812 PRINT  CHR$ (4);"VERIFY";ZA$: PRINT  CHR$ (4);"DELETE";ZA$
813 ZA$ = "LINE." + A$: PRINT  CHR$ (4);"OPEN";ZA$: PRINT  CHR$ (4): PRINT  CHR$ (4);"CLOSE"
814 TEXT:HOME: VTAB 5: PRINT "  **WORKING ON: (";ZA$;"): ": GOTO 1005





1005 CC=PEEK(LP):PRINT "ADR: ";LP;"  VAL: ";CC
1010 IF CC=151 THEN A = 1:CC$(A) = "JSR 64600":HTAB 35:PRINT "HOME":GOTO 1095:REM HOME
1011 IF CC=137 THEN A = 1:CC$(1) = "JSR 64313":HTAB 35:PRINT "TEXT":GOTO 1095:REM TEXT
1012 IF CC=58 THEN LP=LP+1:HTAB 35:PRINT ":":GOTO 1005:REM :
1013 IF CC=0 THEN A=0:HTAB35:PRINT "END OF LINE":LP=LP+3:A=0:GOTO 325
1014 IF CC=158 THEN A = 2:CC$(1) = "LDA #63":CC$(2) = "STA 50":HTAB 35:PRINT "INVERSE":GOTO 1095:REM INVERSE
1015 IF CC=157 THEN A = 2:CC$(1) = "LDA #255":CC$(2) = "STA 50":HTAB 35:PRINT "NORMAL":GOTO 1095:REM NORMAL
1016 IF CC=159 THEN A = 2:CC$(1) = "LDA #127":CC$(2) = "STA 50":HTAB 35:PRINT "FLASH":GOTO 1095:REM FLASH
1017 IF CC=136 THEN A = 1:CC$(1) = "JSR 64320":HTAB 35:PRINT "GR":GOTO 1095:REM GR
1018 IF CC=138 GOTO 1080:REM 'ANY PR# COMMAND
1019 IF CC=172 THEN A = 1:CC$(1) = "JMP 30000":HTAB 35:PRINT "RUN":GOTO 1095:REM RUN
1020 IF CC=177 THEN A = 1:CC$(1) = "RTS":HTAB 35:PRINT "RETURN":GOTO 1095:REM RETURN
1021 IF CC=140 THEN GOSUB 1100:SS$=A$:A=1:CC$(1)="JSR "+SS$:HTAB 35:PRINT "CALL ";SS$:GOTO 300:REM CALL
1022 IF CC=176 GOTO 2000:REM GOSUB	
1023 IF CC=171 GOTO 2010:REM GOTO
1024 IF CC=162 GOTO 2020:REM VTAB
1025 IF CC=150 GOTO 2030:REM HTAB
1026 IF CC=143 GOTO 2090:REM VLIN
1027 IF CC=142 GOTO 2100:REM HLIN
1050 IF CC=186 GOTO 3000:REM PRINT
1051 IF CC=185 GOTO 2050:REM POKE
1052 IF CC=160 GOTO 2060:REM COLOR
1053 IF CC=141 GOTO 2070:REM PLOT
1054 IF CC=173 GOTO 9050:REM IF
1055 IF CC=129 GOTO 3100:REM FOR
1056 IF CC=128 THEN A=1:CC$(1)="JMP 976":HTAB 35:PRINT "END":GOTO 1095:REM END


1070 IF CC<91 GOTO 1150:REM 'POSSIBLE VARIABLE?

1078 FOR X=35000 TO LP+5:PRINT PEEK(X);" ";:NEXT
1079 PRINT "END OF COMMANDS":END


1080 LP=LP+1:CC=PEEK(LP):CC=CC-48:HTAB 35:PRINT "PR#";CC
1081 IF CC=0 THEN CC$(1) = "LDA #21":CC$(2)="JSR 49920":A = 2:GOTO 1095
1082 IF CC=3 THEN CC$(1) = "JSR 49920":CC$(2) = "JSR 64600":CC$(3) = "JSR 1002":A = 3: GOTO 1095
1083 PRINT "NO CODE FOR CURRENT PR#";CC:STOP


1095 LP=LP+1:GOTO 300



1100 A$="":REM NUMBER GETTER!
1101 LP=LP+1:AK=PEEK(LP)
1102 IF AK=58 THEN RETURN
1103 IF AK=0 THEN RETURN
1104 IF AK=44 THEN RETURN
1105 IF AK=197 THEN RETURN
1106 IF AK=34 THEN RETURN
1107 IF AK=44 THEN RETURN
1108 IF AK=208 THEN RETURN
1109 IF AK=207 THEN RETURN
1110 IF AK=209 THEN RETURN
1111 IF AK=41 THEN RETURN
1112 IF AK=40 THEN RETURN
1113 IF AK=200 THEN RETURN
1114 IF AK=201 THEN RETURN
1115 IF AK=202 THEN RETURN
1116 IF AK=203 THEN RETURN
1117 IF AK=196 THEN RETURN
1118 IF AK=171 THEN LP=LP-1:RETURN
1119 IF AK=193 THEN RETURN

1120 A$=A$+CHR$(AK):GOTO 1101


REM----------------*VARIABLE TAKE CARE OF/LET SUBSTRUCTURE?
1150 LP=LP-1:GOSUB 1100:EA$=A$:LP=LP+1:EB=PEEK(LP):LP=LP+1
1151 IF EB=216 GOTO 5300:REM PDL
1152 IF EB=226 GOTO 2040:REM PEEK
1153 IF EB=215 GOTO 2080:REM SCRN
1154 

1160 LP=LP-2:GOSUB 1100
1161 EB=PEEK(LP)
1162 IF EB=58 GOTO 9000:REM SIMPLE A=B
1163 IF EB=0 GOTO 9000:REM SIMPLE A=B
1164 IF EB=200 GOTO 9010:REM ADDITION
1165 IF EB=201 GOTO 9020:REM SUBTRACTION
1166 IF EB=202 GOTO 9060:REM MULTIPLICATION
1167 IF EB=203 GOTO 9040:REM DIVISION
1189 PRINT "ERROR AT VARAIBLE LET SUBSTRUCTURE":STOP


REM----------------*GOSUB
2000 CC$(1) = "COMMAND":CC$(2) = "GOSUB"
2001 GOSUB 1100:CC$ = "LINE." + A$:HTAB 35:PRINT "GOSUB ";CC$
2002 CC$(3) = CC$:ZP$ = ZA$:ZA$ = CC$(3): GOSUB 350:ZA$ = ZP$:A = 3: GOTO 300


REM----------------*GOTO
2010 CC$(1) = "COMMAND":CC$(2) = "GOTO"
2011  GOSUB 1100:CC$ = "LINE." + A$:HTAB 35:PRINT "GOTO ";CC$
2012  CC$(3) = CC$:ZP$ = ZA$:ZA$ = CC$(3): GOSUB 350:ZA$ = ZP$:A = 3:GOTO 300


REM----------------*VTAB  BETTER FIX V1.38
2020  GOSUB 1100:SS$=A$:GOSUB 400:HTAB 35:PRINT "VTAB ";SS$
2021  IF T=1 THEN V=V-1:CC$ =  STR$ (V):CC$(1) = "LDA #" + CC$:CC$(2)="STA 37":CC$(3)="JSR 64546":A=3:GOTO 300
2022  CC$ =  STR$ (IX):CC$(1) = "LDX " + CC$:CC$(2)="DEX":CC$(3)="TXA"
2025 CC$(3)="TXA":CC$(4)="STA 37":CC$(5)="JSR 64546":A=5:GOTO 300


REM----------*HTAB V2
2030 GOSUB 1100:SS$=A$:GOSUB 400:CC$(2)="STX 36":HTAB 35:PRINT "HTAB ";SS$
2031 IF T = 1 THEN V = V - 1:CC$ =  STR$ (V):CC$(1) = "LDX #" + CC$:A=2:GOTO 300
2032 A=3:CC$ =  STR$ (IX):CC$(1) = "LDX " + CC$:CC$(2)="DEX":CC$(3)="STX 36":GOTO 300


REM---------*PEEK V3
2040 SX$=A$:PRINT LP:GOSUB 1100:SY$=A$:LP=LP+1
2042 SS$ = SY$: GOSUB 400:IF T = 1 THEN X = X:CC$ =  STR$ (V):CC$(1) = "LDA " + CC$: GOTO 2047

2043 CC$ =  STR$ (IX):CC$(1) = "LDX " + CC$:CC$ =  STR$ (IY):CC$(2) = "LDY " + CC$
2044 CC$(3)="STX 113":CC$(4)="STY 114":CC$(5)="LDY #0":CC$(6)="LDA (71),Y"
2045 SS$ = SX$: GOSUB 400:C$ =  STR$ (IX):CC$(7) = "STA " + C$
2046 CC$ =  STR$ (IY):CC$(8) = "STY " + CC$:A = 8:HTAB 35:PRINT SX$;" = PEEK (";SY$;")":GOTO 300

2047 SS$ = SX$: GOSUB 400:C$ =  STR$ (IX):CC$(2) = "STA " + C$
2048 CC$(3)="LDA #0":CC$=STR$(IY):CC$(4)="STA "+CC$:A=4:HTAB 35:PRINT SX$;" = PEEK (";SY$;")"
2049 HTAB 35:INPUT "DOUBLE PEEK (Y?): ";Y$:GOTO 2058
2058 IF Y$="Y" THEN SX=VAL(SY$):SX=SX+1:CC$(3)="LDA "+STR$(SX)
2059 GOTO 300


REM----------------*POKE V2
2050  GOSUB 1100:C =  VAL (A$)
2051  GOSUB 1100:SS$ = A$:GOSUB 400:A=4: IF T = 1 THEN GOTO 2055
2052  C$ =  STR$ (IX):D$=STR$(IY):CC$(1) = "LDA " + C$:C$ =  STR$ (C):GOTO 2056
2055  CC$ =  STR$ (V):CC$(1) = "LDA #" + CC$:C$ =  STR$ (C)
2056 CC$(2) = "STA " + C$:A=2:HTAB 35:PRINT "POKE ";C;","SS$:GOTO 300


REM----------------*COLOR
2060 GOSUB 1100:SS$=A$:HTAB 35:PRINT "COLOR= ";SS$:GOSUB 400
2061 IF T = 1 THEN CC$ =  STR$ (V):CC$(1) = "LDA #" + CC$:GOTO 2065
2062 CC$ =  STR$ (IX):CC$(1) = "LDA " + CC$
2065 CC$(2) = "JSR 63588":A = 2: GOTO 300


REM----------------*PLOT
2070 GOSUB 1100:SX$=A$
2071 GOSUB 1100:SY$=A$:HTAB 35:PRINT "PLOT ";SX$;",";SY$
2072 SS$ = SX$: GOSUB 400: IF T = 1 THEN X = X:CC$ =  STR$ (V):CC$(1) = "LDY #" + CC$: GOTO 2074
2073 CC$ =  STR$ (IX):CC$(1) = "LDY " + CC$
2074 SS$ = SY$: GOSUB 400: IF T = 1 THEN X = X:CC$ =  STR$ (V):CC$(2) = "LDA #" + CC$: GOTO 2076
2075 CC$ =  STR$ (IX):CC$(2) = "LDA " + CC$
2076 CC$(3) = "JSR 63488":A = 3: GOTO 300


REM----------------*SCRN
2080 SZ$=EA$
2081 LP=LP-1:GOSUB 1100:SX$=A$
2082 GOSUB 1100:SY$=A$
2083 SS$ = SX$: GOSUB 400: IF T = 1 THEN CC$ =  STR$ (V):CC$(1) = "LDY #" + CC$: GOTO 2085
2084 CC$ =  STR$ (IX):CC$(1) = "LDY " + CC$
2085 SS$ = SY$: GOSUB 400: IF T = 1 THEN CC$ =  STR$ (V):CC$(2) = "LDA #" + CC$: GOTO 2087
2086 CC$ =  STR$ (IX):CC$(2) = "LDA " + CC$
2087 SS$ = SZ$:IX = 0: GOSUB 400:DD$ =  STR$ (IX)
2088 CC$(3) = "JSR 63601":CC$(4) = "STA " + DD$:A = 4:LP=LP+1
2089 HTAB 35:PRINT EA$;" = SCRN (";SX$;",";SY$;")":GOTO 300


REM----------------*VLIN
2090 CC$(3) = "STA 45":CC$(5) = "JSR 63528":A = 5
2091  GOSUB 1100:SX$=A$
2092  GOSUB 1100:SY$=A$
2093  GOSUB 1100:SZ$=A$:HTAB 35:PRINT "VLIN ";SX$;",";SY$;" AT ";SZ$
2094 SS$ = SZ$: GOSUB 400: IF T = 1 THEN CC$ =  STR$ (V):CC$(1) = "LDY #" + CC$: GOTO 2096
2095 CC$ =  STR$ (IX):CC$(1) = "LDY " + CC$
2096 SS$ = SY$: GOSUB 400: IF T = 1 THEN CC$ =  STR$ (V):CC$(2) = "LDA #" + CC$: GOTO 2098
2097 CC$ =  STR$ (IX):CC$(2) = "LDA " + CC$
2098 SS$ = SX$: GOSUB 400: IF T = 1 THEN CC$ =  STR$ (V):CC$(4) = "LDA #" + CC$: GOTO 300
2099 CC$ =  STR$ (IX):CC$(4) = "LDA " + CC$: GOTO 300


REM----------------*HLIN
2100 CC$(3) = "STY 44":CC$(5) = "JSR 63513":A = 5
2101 GOSUB 1100:SX$=A$
2102 GOSUB 1100:SY$=A$
2103 GOSUB 1100:SZ$=A$:HTAB 35:PRINT "HLIN ";SX$;",";SY$;" AT ";SZ$
2104 SS$ = SZ$: GOSUB 400: IF T = 1 THEN CC$ =  STR$ (V):CC$(1) = "LDA #" + CC$: GOTO 2106
2105 CC$ =  STR$ (IX):CC$(1) = "LDA " + CC$
2106 SS$ = SY$: GOSUB 400: IF T = 1 THEN CC$ =  STR$ (V):CC$(2) = "LDY #" + CC$: GOTO 2108
2107 CC$ =  STR$ (IX):CC$(2) = "LDY " + CC$
2108 SS$ = SX$: GOSUB 400: IF T = 1 THEN CC$ =  STR$ (V):CC$(4) = "LDY #" + CC$: GOTO 300
2109 CC$ =  STR$ (IX):CC$(4) = "LDY " + CC$: GOTO 300


REM----------------*PRINT v4
3000  LP=LP+1
3001  IF PEEK(LP)=34 THEN GOTO 3010
3002  GOTO 3020

3010 A=1:GOSUB 1100:V$=A$:HTAB 35:PRINT "PRINT ";A$
3011 V =  LEN (V$): IF V = 0 THEN STOP
3012 FOR U = 1 TO V:VV$ =  MID$ (V$,U,1):VV =  ASC (VV$):VV$ =  STR$ (VV+128)
3013 CC$(A) = "LDA #" + VV$:A = A + 1:CC$(A) = "JSR 65005":A = A + 1: NEXT 
3014 A=A-1:LP=LP-1:GOTO 3029


3020 LP=LP-1:GOSUB 1100:SS$=A$:HTAB 35:PRINT "PRINT ";A$
3021 GOSUB 400:EE$ =  STR$ (IX):FF$ =  STR$ (IY):GG$ =  STR$ (IZ)
3022 CC$(1) = "LDY " + GG$:CC$(2) = "LDX " + FF$:CC$(3) = "LDA " + EE$
3023 CC$(4) = "COMMAND":CC$(5) = "GOSUB":CC$(6) = "LINE.24BITPRINT"
3024 ZY$ = ZA$:ZA$ = CC$(6):GOSUB 350:ZA$ = ZY$:A = 6:LP=LP-2

3029 A=A+1:CC$(A)="LDA #141":A=A+1:CC$(A)="JSR 65005":LP=LP+1:GOTO 1095


REM----------------FOR NEXT/LOOP ULTRA SPEED 2BYTE VERSION!
3100 GOSUB 1100:EA$=A$:GOSUB 1100:EB$=A$:GOSUB 1100:EC$=A$:LP=LP+1:GOSUB 1100:ED$=A$:LP=LP+2
3101 SX$=EB$:SS$=SX$:GOSUB 400:I = V
3102 SY$=EC$:SS$=SY$:GOSUB 400:J = V:JJ$=ED$:JJ$="LINE."+JJ$

3103 H = J - I: GOSUB 700:CC$ =  STR$ (HX(2)):DD$ =  STR$ (HX(1)):CC$(4) = "LDA #" + CC$:CC$(6) = "LDA #" + DD$
3104 CC$(8) = "COMMAND":CC$(9) = "GOSUB":CC$(10) = JJ$
3105 CC$(1) = "INC 30007":CC$(2) = "INC 30007":CC$(3) = "LDX 30007":CC$(5) = "STA 30006,X"
3106 CC$(7) = "STA 30007,X":CC$(11) = "LDX 30007":CC$(12) = "LDA 30006,X":CC$(13) = "BNE 8":CC$(14) = "LDA 30007,X"
3107 CC$(15) = "BEQ 10":CC$(16) = "DEC 30007,X":CC$(17) = "DEC 30006,X":CC$(18) = "LDA #0":CC$(19) = "BEQ -26"
3108 CC$(20) = "DEC 30007":CC$(21) = "DEC 30007":ZP$=ZA$:ZA$ = CC$(10): GOSUB 350:ZA$ = ZP$:A = 21: GOTO 300


REM----------------IF 16BIT SUBSTRUCTURE
3200  SF$=EA$:SG$=EC$:ON EB GOTO 3210,3220,3230


REM----------------16BIT IFS =
3210 SS$ = SF$: GOSUB 400:EE$ =  STR$ (IX):FF$ =  STR$ (IY):SS$ = SG$: GOSUB 400: IF T = 1 GOTO 3212
3211 GG$ =  STR$ (IX):HH$ =  STR$ (IY):CC$(2) = "CMP " + HH$:CC$(5) = "CMP " + GG$:CC$(3) = "BNE +8": GOTO 3213
3212 H = V: GOSUB 700:GG$ =  STR$ (HX(2)):HH$ =  STR$ (HX(1)):CC$(2) = "CMP #" + HH$:CC$(5) = "CMP #" + GG$:CC$(3) = "BNE +7"
3213 CC$(1) = "LDA " + FF$:CC$(4) = "LDA " + EE$
3214 CC$(6) = "BEQ +3":GOTO 3234


REM----------------16BIT IFS >
3220 SS$ = SF$: GOSUB 400:EE$ =  STR$ (IX):FF$ =  STR$ (IY):SS$ = SG$: GOSUB 400: IF T = 1 GOTO 3222
3221 GG$ =  STR$ (IX):HH$ =  STR$ (IY):CC$(2) = "CMP " + FF$:CC$(3) = "BNE +6":CC$(5) = "CMP " + EE$: GOTO 3223
3222 H = V: GOSUB 700:GG$ =  STR$ (HX(2)):HH$ =  STR$ (HX(1)):CC$(2) = "CMP " + FF$:CC$(3) = "BNE +5":CC$(5) = "CMP " + EE$
3223 BZ =  LEN (HH$): IF BZ > 4 THEN CC$(1) = "LDA " + HH$
3225 BZ =  LEN (GG$): IF BZ > 4 THEN CC$(4) = "LDA " + GG$: GOTO 3227
3226 CC$(1) = "LDA #" + HH$:CC$(4) = "LDA #" + GG$
3227 CC$(6) = "BCC +3":GOTO 3234


REM----------------16BIT IFS <
3230  SS$ = SF$: GOSUB 400:EE$ =  STR$ (IX):FF$ =  STR$ (IY):SS$ = SG$: GOSUB 400: IF T = 1 GOTO 3232
3231  GG$ =  STR$ (IX):HH$ =  STR$ (IY):CC$(2) = "CMP " + HH$:CC$(3) = "BNE +6":CC$(5) = "CMP " + GG$: GOTO 3233
3232 H = V: GOSUB 700:GG$ =  STR$ (HX(2)):HH$ =  STR$ (HX(1)):CC$(2) = "CMP #" + HH$:CC$(3) = "BNE +5":CC$(5) = "CMP #" + GG$
3233 CC$(1) = "LDA " + FF$:CC$(4) = "LDA " + EE$:CC$(6) = "BCC +3"
3234 CC$(7) = "COMMAND":CC$(8) = "NEXT":CC$(9) = ZA$:A = 9:LP=LP+1:GOTO 300


REM----------------16BIT EQUALS
3310 SX$=EA$:SY$=EC$
3313 SS$ = SX$: GOSUB 400:CC$ =  STR$ (IX):DD$ =  STR$ (IY):CC$(2) = "STA " + CC$
3314 CC$(4) = "STA " + DD$:SS$ = SY$: GOSUB 400:IF T = 1 GOTO 3316
3315 EE$ =  STR$ (IX):CC$(1) = "LDA " + EE$:FF$ =  STR$ (IY):CC$(3) = "LDA " + FF$: GOTO 3319
3316 H = V: GOSUB 700:EE$ =  STR$ (HX(2)):FF$ =  STR$ (HX(1)):CC$(1) = "LDA #" + EE$:CC$(3) = "LDA #" + FF$
3319 A = 4: PRINT : HTAB 44: PRINT "--> [ ";SX$;" = ";SY$;" ] <--":GOTO 300


REM----------------16BIT ADDITION
3320 SX$=EA$:SY$=EC$:SZ$=ED$
3324 SS$ = SX$: GOSUB 400:EE$ =  STR$ (IX):FF$ =  STR$ (IY):CC$(1) = "CLC":CC$(4) = "STA " + EE$
3325 CC$(7) = "STA " + FF$:SS$ = SY$: GOSUB 400: IF T = 1 GOTO 3327
3326 GG$ =  STR$ (IX):CC$(2) = "LDA " + GG$:HH$ =  STR$ (IY):CC$(5) = "LDA " + HH$: GOTO 3328
3327 H = V: GOSUB 700:GG$ =  STR$ (HX(2)):HH$ =  STR$ (HX(1)):CC$(2) = "LDA #" + GG$:CC$(5) = "LDA #" + HH$
3328 SS$ = SZ$: GOSUB 400: IF T = 1 GOTO 3330
3329 II$ =  STR$ (IX):CC$(3) = "ADC " + II$:JJ$ =  STR$ (IY):CC$(6) = "ADC " + JJ$: GOTO 3331
3330 H = V: GOSUB 700:II$ =  STR$ (HX(2)):JJ$ =  STR$ (HX(1)):CC$(3) = "ADC #" + II$:CC$(6) = "ADC #" + JJ$
3331 A = 7: PRINT : HTAB 44: PRINT "--> [ ";SX$;" = ";SY$;" + ";SZ$;" ] <--": GOTO 300


REM----------------16BIT SUBTRACTION
3340 SX$=EA$:SY$=EC$:SZ$=ED$
3344 SS$ = SX$: GOSUB 400:EE$ =  STR$ (IX):FF$ =  STR$ (IY):CC$(1) = "SEC":CC$(4) = "STA " + EE$:CC$(7) = "STA " + FF$
3345 SS$ = SY$: GOSUB 400: IF T = 1 GOTO 3347
3346 GG$ =  STR$ (IX):CC$(2) = "LDA " + GG$:HH$ =  STR$ (IY):CC$(5) = "LDA " + HH$: GOTO 3348
3347 H = V: GOSUB 700:GG$ =  STR$ (HX(2)):HH$ =  STR$ (HX(1)):CC$(2) = "LDA #" + GG$:CC$(5) = "LDA #" + HH$
3348 SS$ = SZ$: GOSUB 400: IF T = 1 GOTO 3350
3349 II$ =  STR$ (IX):CC$(3) = "SBC " + II$:JJ$ =  STR$ (IY):CC$(6) = "SBC " + JJ$: GOTO 3351
3350 H = V: GOSUB 700:II$ =  STR$ (HX(2)):JJ$ =  STR$ (HX(1)):CC$(3) = "SBC #" + II$:CC$(6) = "SBC #" + JJ$
3351 A = 7: PRINT : HTAB 44: PRINT "--> [ ";SX$;" = ";SY$;" - ";SZ$;" ] <--": GOTO 300


REM----------------16BIT MULTIPLICATION
3360 SX$=EA$:SY$=EC$:SZ$=ED$
3364 SS$ = SX$: GOSUB 400:EE$ =  STR$ (IX):FF$ =  STR$ (IY):SS$ = SY$: GOSUB 400
3365 IF T = 1 THEN H = V: GOSUB 700:GG$ =  STR$ (HX(2)):HH$ =  STR$ (HX(1)):CC$(1) = "LDX #" + GG$:CC$(2) = "LDY #" + HH$: GOTO 3367
3366 GG$ =  STR$ (IX):HH$ =  STR$ (IY):CC$(1) = "LDX " + GG$:CC$(2) = "LDY " + HH$
3367 CC$(3) = "STX 30003":CC$(4) = "STY 30004": SS$ = SZ$: GOSUB 400
3368 IF T = 1 THEN H = V: GOSUB 700:II$ =  STR$ (HX(2)):JJ$ =  STR$ (HX(1)):CC$(5) = "LDX #" + II$:CC$(6) = "LDY #" + JJ$: GOTO 3370
3369 II$ =  STR$ (IX):JJ$ =  STR$ (IY):CC$(5) = "LDX " + II$:CC$(6) = "LDY " + JJ$
3370 CC$(7) = "COMMAND":CC$(8) = "GOSUB":CC$(9) = "LINE.16BITMULT"
3371 CC$(10) = "STX " + EE$:CC$(11) = "STY " + FF$:ZY$ = ZA$:ZA$ = CC$(9): GOSUB 350:ZA$ = ZY$
3372 A = 11: PRINT : HTAB 44: PRINT "--> [ ";SX$;" = ";SY$;" * ";SZ$;" ] <--": GOTO 300


REM----------------16BIT MULTIPLICATION
3380  SX$=EA$:SY$=EC$:SZ$=ED$
3384 SS$=SX$:GOSUB 400:EE$=STR$(IX):FF$=STR$(IY):SS$=SY$:GOSUB 400
3385 IF T=1 THEN H=V:GOSUB 700:GG$=STR$(HX(2)):HH$=STR$(HX(1)):CC$(1)="LDX #"+GG$:CC$(2)="LDY #"+HH$:GOTO 3387
3386 GG$=STR$(IX):HH$=STR$(IY):CC$(1)="LDX "+GG$:CC$(2)="LDY "+HH$
3387 CC$(3) = "STX 30003":CC$(4) = "STY 30004":SS$ = SZ$: GOSUB 400
3388 IF T = 1 THEN H = V: GOSUB 700:II$ =  STR$ (HX(2)):JJ$ =  STR$ (HX(1)):CC$(5) = "LDX #" + II$:CC$(6) = "LDY #" + JJ$:GOTO 3390
3389 II$ =  STR$ (IX):JJ$ =  STR$ (IY):CC$(5) = "LDX " + II$:CC$(6) = "LDY " + JJ$
3390 CC$(7) = "COMMAND":CC$(8) = "GOSUB":CC$(9) = "LINE.16BITDIV"
3391 CC$(10) = "STX " + EE$:CC$(11) = "STY " + FF$
3392 ZY$ = ZA$:ZA$ = CC$(9): GOSUB 350:ZA$ = ZY$
3393 A=11:PRINT : HTAB 44: PRINT "--> [ ";SX$;" = ";SY$;" / ";SZ$;" ] <--":GOTO 300


REM---------------16BIT DIV*2
3410 SS$ = SX$: GOSUB 400:CC$ =  STR$ (IX):DD$ =  STR$ (IY)
3412 CC$(1) = "LSR " + DD$:CC$(2) = "ROR " + CC$:A = 2: GOTO 300


REM---------------16BIT MULT*2
3420 SS$ = SX$: GOSUB 400:CC$ =  STR$ (IX):DD$ =  STR$ (IY)
3422 CC$(1) = "ASL " + CC$:CC$(2) = "ROL " + DD$:A = 2: GOTO 300


REM-------------16BIT MULT*10
3430 SS$ = SX$: GOSUB 400:CC$ =  STR$ (IX):DD$ =  STR$ (IY)
3432 CC$(1) = "LDA " + DD$:CC$(2) = "PHA":CC$(3) = "LDA " + CC$:CC$(4) = "ASL " + CC$
3433 CC$(5) = "ROL " + DD$:CC$(6) = "ASL " + CC$:CC$(7) = "ROL " + DD$
3434 CC$(8) = "CLC":CC$(9) = "ADC " + CC$:CC$(10) = "STA " + CC$:CC$(11) = "PLA":CC$(12) = "ADC " + DD$
3435 CC$(13) = "STA " + DD$:CC$(14) = "ASL " + CC$:CC$(15) = "ROL " + DD$:A = 15: GOTO 300


REM------------16BIT INCREASE
3440  SS$=SX$: GOSUB 400:EE$ =  STR$ (IX):FF$ =  STR$ (IY)
3442  CC$(1) = "INC " + EE$:CC$(2) = "BNE 3":CC$(3) = "INC " + FF$:A = 3: GOTO 300


REM------------16BIT DECREASE
3450  SS$=SX$:GOSUB 400:EE$ =  STR$ (IX):FF$ =  STR$ (IY)
3452  CC$(1) = "LDA " + EE$:CC$(2) = "BNE 3":CC$(3) = "DEC " + FF$:CC$(4) = "DEC " + EE$:A = 4: GOTO 300


REM----------------8BIT EQUALS
5010  SX$=EA$:SY$=EC$
5013 SS$ = SX$: GOSUB 400:CC$ =  STR$ (IX):CC$(2) = "STA " + CC$
5014 SS$ = SY$: GOSUB 400: IF T = 1 GOTO 5016
5015 DD$ =  STR$ (IX):CC$(1) = "LDA " + DD$:A = 2: GOTO 300
5016 DD$ =  STR$ (V):CC$(1) = "LDA #" + DD$:A = 2: GOTO 300


REM----------------8BIT ADDITION
5020  SX$=EA$:SY$=EC$:SZ$=ED$
5024 SS$ = SX$: GOSUB 400:CC$ =  STR$ (IX):CC$(1) = "CLC":CC$(4) = "STA " + CC$
5025 SS$ = SY$: GOSUB 400: IF T = 1 THEN DD$ =  STR$ (V):CC$(3) = "ADC #" + DD$: GOTO 5027
5026 DD$ =  STR$ (IX):CC$(3) = "ADC " + DD$
5027 SS$ = SZ$: GOSUB 400: IF T = 1 THEN EE$ =  STR$ (V):CC$(2) = "LDA #" + EE$: GOTO 5029
5028 EE$ =  STR$ (IX):CC$(2) = "LDA " + EE$
5029 A = 4: GOTO 300


REM----------------8BIT SUBTRACTION
5030  SX$=EA$:SY$=EC$:SZ$=ED$
5034 SS$ = SX$: GOSUB 400:CC$ =  STR$ (IX):CC$(1) = "SEC":CC$(4) = "STA " + CC$
5035 SS$ = SY$: GOSUB 400: IF T = 1 THEN DD$ =  STR$ (V):CC$(2) = "LDA #" + DD$: GOTO 5037
5036 DD$ =  STR$ (IX):CC$(2) = "LDA " + DD$
5037 SS$ = SZ$: GOSUB 400: IF T = 1 THEN EE$ =  STR$ (V):CC$(3) = "SBC #" + EE$: GOTO 5039
5038 EE$ =  STR$ (IX):CC$(3) = "SBC " + EE$
5039 A = 4: GOTO 300


REM----------------8BIT MULTIPLICATION
5040 SX$=EA$:SY$=EC$:SZ$=ED$
5044  SS$ = SX$: GOSUB 400:CC$ =  STR$ (IX):DD$ =  STR$ (IY)
5045  CC$(3) = "COMMAND":CC$(4) = "GOSUB":CC$(5) = "LINE.8BITMULT":CC$(6) = "STA " + CC$:CC$(7) = "STY " + DD$
5046  SS$ = SY$: GOSUB 400: IF T = 1 THEN EE$ =  STR$ (V):CC$(1) = "LDX #" + EE$: GOTO 5048
5047  EE$ =  STR$ (IX):CC$(1) = "LDX " + EE$
5048  SS$ = SZ$: GOSUB 400: IF T = 1 THEN FF$ =  STR$ (V):CC$(2) = "LDY #" + FF$: GOTO 5050
5049 FF$ =  STR$ (IX):CC$(2) = "LDY " + FF$
5050 A = 7:ZP$ = ZA$:ZA$ = CC$(5): GOSUB 350:ZA$ = ZP$: GOTO 300


REM----------------8BIT DIVISION
5060 SX$=EA$:SY$=EC$:SZ$=ED$
5064  SS$ = SX$: GOSUB 400:CC$ =  STR$ (IX):DD$ =  STR$ (IY):CC$(1) = "LDA #0":CC$(2) = "STA " + DD$
5065  SS$ = SY$: GOSUB 400: IF T = 1 THEN EE$ =  STR$ (V):CC$(3) = "LDX #" + EE$: GOTO 5067
5066 EE$ =  STR$ (IX):CC$(3) = "LDX " + EE$
5067 SS$ = SZ$: GOSUB 400: IF T = 1 THEN FF$ =  STR$ (V):CC$(4) = "LDY #" + FF$: GOTO 5069
5068 FF$ =  STR$ (IX):CC$(4) = "LDY " + FF$
5069 CC$(5) = "COMMAND":CC$(6) = "GOSUB":CC$(7) = "LINE.8BITDIV"
5070 CC$(8) = "LDA 30004":CC$(9) = "STA " + CC$:A = 9:ZP$ = ZA$:ZA$ = CC$(7): GOSUB 350:ZA$ = ZP$: GOTO 300


REM----------------8BIT A=A/2
5110 SS$ = SX$: GOSUB 400:CC$ =  STR$ (IX):CC$(1) = "LSR " + CC$:A = 1: GOTO 300


REM----------------8BIT MULT*2
5120 SS$ = SX$: GOSUB 400:CC$ =  STR$ (IX):CC$(1) = "ASL " + CC$:A = 1: GOTO 300


REM----------------8BIT INC
5130 SS$ = SX$:GOSUB 400:EE$ =  STR$ (IX):CC$(1) = "INC " + EE$:A = 1: GOTO 300


REM----------------8BIT DEC
5140  SS$=SX$:GOSUB 400:EE$ =  STR$ (IX):CC$(1) = "DEC " + EE$:A = 1: GOTO 300


REM----------------8BIT IFS
5200  SF$=EA$:SG$=EC$:ON EB GOTO 5210,5230,5220


REM----------------8BIT IFS =
5210 SS$ = SF$: GOSUB 400:EE$ =  STR$ (IX):CC$(1) = "LDA " + EE$:CC$(3) = "BEQ +3"
5211 SS$ = SG$: GOSUB 400: IF T = 1 THEN  GOTO 5213
5212 GG$ =  STR$ (IX):CC$(2) = "CMP " + GG$: GOTO 5215
5213 H = V: GOSUB 700:GG$ =  STR$ (HX(2)):CC$(2) = "CMP #" + GG$
5215 CC$(4) = "COMMAND":CC$(5) = "NEXT":CC$(6) = ZA$:A = 6:LP=LP+1:GOTO 300


REM----------------8BIT IFS <
5220 SS$ = SF$: GOSUB 400:EE$ =  STR$ (IX):CC$(1) = "LDA " + EE$:CC$(3) = "BCC +3": GOTO 5211


REM----------------8BIT IFS >
5230  SS$ = SF$: GOSUB 400:EE$ =  STR$ (IX)
5231  SS$ = SG$: GOSUB 400:IF T = 1 GOTO 5233
5232  GG$ =  STR$ (IX):CC$(1) = "LDA " + GG$:GOTO 5234
5233  H = V:GG$ =  STR$ (H):CC$(1) = "LDA #" + GG$
5234  CC$(2) = "CMP " + EE$:CC$(3) = "BCC +3": GOTO 5215


REM----------------PADDLE CODE TO VARIABLE
5300  GOSUB 1100:D=VAL(A$):HTAB 35:PRINT EA$;" = PDL(";A$;")"
5301 D=D-1:CC$=STR$(D):CC$(1)="LDX #"+CC$:CC$(2)="JSR 64286":CC$(3)="STY ":SZ$=EA$
5302 SS$=SZ$:GOSUB 400:CC$=STR$(IX):CC$(3)=CC$(3)+CC$:A=3:LP=LP+1:GOTO 300


REM----------------24 BIT EQUALS
7100  SX$=EA$:SY$=EC$
7103 SS$ = SX$: GOSUB 400:CC$ =  STR$ (IX):DD$ =  STR$ (IY):EE$=STR$(IZ)
7104 CC$(2) = "STA " + CC$:CC$(4)="STA "+DD$:CC$(6)="STA "+EE$
7105 SS$=SY$:GOSUB 400:IF T=1 GOTO 7110
7106 EE$=STR$(IX):CC$(1)="LDA "+EE$:FF$=STR$(IY):CC$(3)="LDA "+FF$
7108 GG$=STR$(IZ):CC$(5)="LDA "+GG$
7109 A=6:PRINT : HTAB 44: PRINT "--> [ ";SX$;" = ";SY$;" ] <--": GOTO 300
7110 GG=INT(V/(256*256)):CC$(5)="LDA #"+STR$(GG):H=V-(GG*256*256):GOSUB 700:EE$ =  STR$ (HX(2))
7111 FF$ =  STR$ (HX(1)):CC$(1) = "LDA #" + EE$:CC$(3) = "LDA #" + FF$:GOTO 7109


REM----------------24 BIT ADDITION
7200  SX$=EA$:SY$=EC$:SZ$=ED$
7204 SS$=SX$:GOSUB 400:EE$=STR$(IX):FF$=STR$(IY):GG$=STR$(IZ)
7205 CC$(1)="CLC":CC$(4)="STA "+EE$:CC$(7)="STA "+FF$:CC$(10)="STA "+GG$

7206 SS$=SY$:GOSUB 400:IF T=1 GOTO 7220
7207 HH$=STR$(IX):II$=STR$(IY):JJ$=STR$(IZ)
7208 CC$(2)="LDA "+HH$:CC$(5)="LDA "+II$:CC$(8)="LDA "+JJ$

7209 SS$=SZ$:GOSUB 400:IF T=1 GOTO 7230
7210 KK$=STR$(IX):LL$=STR$(IY):MM$=STR$(IZ)
7211 CC$(3)="ADC "+KK$:CC$(6)="ADC "+LL$:CC$(9)="ADC "+MM$
7214 A=10:PRINT : HTAB 44: PRINT "--> [ ";SX$;" = ";SY$;" + ";SZ$;" ] <--": GOTO 300

7220 GG=INT(V/(256*256)):H=V-(GG*256*256):GOSUB 700
7221 CC$(8)="LDA #"+STR$(GG):H=V-(GG*256*256):GOSUB 700
7222 CC$(2) ="LDA #"+STR$ (HX(2)):CC$(5)="LDA #"+STR$(HX(1)):GOTO 7209

7230 GG=INT(V/(256*256)):H=V-(GG*256*256):GOSUB 700
7231 CC$(9)="ADC #"+STR$(GG):H=V-(GG*256*256):GOSUB 700
7232 CC$(3) ="ADC #"+STR$ (HX(2)):CC$(6)="ADC #"+STR$(HX(1)):GOTO 7214


REM----------------24BIT SUBTRACTION
7300 SX$=EA$:SY$=EC$:SZ$=ED$
7304 SS$=SX$:GOSUB 400:EE$=STR$(IX):FF$=STR$(IY):GG$=STR$(IZ)
7305 CC$(1)="SEC":CC$(4)="STA "+EE$:CC$(7)="STA "+FF$:CC$(10)="STA "+GG$

7306 SS$=SY$:GOSUB 400:IF T=1 GOTO 7320
7307 HH$=STR$(IX):II$=STR$(IY):JJ$=STR$(IZ)
7308 CC$(2)="LDA "+HH$:CC$(5)="LDA "+II$:CC$(8)="LDA "+JJ$

7309 SS$=SZ$:GOSUB 400:IF T=1 GOTO 7330
7310 KK$=STR$(IX):LL$=STR$(IY):MM$=STR$(IZ)
7311 CC$(3)="SBC "+KK$:CC$(6)="SBC "+LL$:CC$(9)="SBC "+MM$
7314 A=10:PRINT : HTAB 44: PRINT "--> [ ";SX$;" = ";SY$;" - ";SZ$;" ] <--": GOTO 300

7320 GG=INT(V/(256*256)):H=V-(GG*256*256):GOSUB 700
7321 CC$(8)="LDA #"+STR$(GG):H=V-(GG*256*256):GOSUB 700
7322 CC$(2) ="LDA #"+STR$ (HX(2)):CC$(5)="LDA #"+STR$(HX(1)):GOTO 7309

7330 GG=INT(V/(256*256)):H=V-(GG*256*256):GOSUB 700
7331 CC$(9)="SBC #"+STR$(GG):H=V-(GG*256*256):GOSUB 700
7332 CC$(3) ="SBC #"+STR$ (HX(2)):CC$(6)="SBC #"+STR$(HX(1)):GOTO 7314


REM----------------24BIT A=A/2
7410 SS$ = SX$: GOSUB 400:CC$ =  STR$ (IX):DD$ =  STR$ (IY):EE$=STR$(IZ)
7412 CC$(1)="LSR "+EE$:CC$(2) = "ROR " + DD$:CC$(3) = "ROR " + CC$:A = 3: GOTO 300


REM----------------24BIT A=A*2
7420 SS$ = SX$: GOSUB 400:CC$ =  STR$ (IX):DD$ =  STR$ (IY):EE$=STR$(IZ)
7422 CC$(1) = "ASL " + CC$:CC$(2) = "ROL " + DD$:CC$(3)="ROL "+EE$:A = 3: GOTO 300


REM----------------24BIT INC
7440  SS$=SX$:GOSUB 400:EE$ =  STR$ (IX):FF$ =  STR$ (IY):GG$=STR$(IZ)
7442  CC$(1) = "INC " + EE$:CC$(2) = "BNE 8":CC$(3) = "INC " + FF$
7443  CC$(4)="BNE 3":CC$(5)="INC "+GG$:A=5:GOTO 300


REM----------------24BIT DEC
7450 SS$=SX$:GOSUB 400:EE$ =  STR$ (IX):FF$ =  STR$ (IY):GG$=STR$(IZ)
7452 CC$(1)="LDA "+EE$:CC$(2)="BNE 11":CC$(3)="LDA "+FF$:CC$(4)="BNE 3"
7453 CC$(5)="DEC "+GG$:CC$(6)="DEC "+FF$:CC$(7)="DEC "+EE$:A=7:GOTO 300


REM----------------IF 24BIT SUBSTRUCTURE
7500  SF$=EA$:SG$=EC$:ON EB GOTO 7510,7700,7600

REM----------------IF 24BIT =
7510 SS$=SF$:GOSUB 400:EE$=STR$(IX):FF$=STR$(IY):GG$=STR$(IZ)
7511 CC$(1)="LDA "+GG$:CC$(4)="LDA "+FF$:CC$(7)="LDA "+EE$
7513 CC$(10)="COMMAND":CC$(11)="NEXT":CC$(12)=ZA$
7514 CC$(3)="BNE 16":CC$(6)="BNE 8":CC$(9)="BEQ 3"

7515 SS$=SG$:GOSUB 400:IF T=1 GOTO 7520
7516 HH$=STR$(IX):II$=STR$(IY):JJ$=STR$(IZ)
7517 CC$(2)="CMP "+JJ$:CC$(5)="CMP "+II$:CC$(8)="CMP "+HH$
7519 A=12:LP=LP+1:GOTO 300

7520 GG=INT(V/(256*256)):H=V-(GG*256*256):CC$(2)="CMP #"+STR$(GG):H=V-(GG*256*256):GOSUB 700
7521 CC$(5)="CMP #"+STR$(HX(1)):CC$(8)="CMP #"+STR$(HX(2)):GOTO 7519




REM-----------------IF 24BIT <
7600 SS$=SF$:GOSUB 400:EE$=STR$(IX):FF$=STR$(IY):GG$=STR$(IZ)
7601 CC$(1)="LDA "+GG$:CC$(5)="LDA "+FF$:CC$(9)="LDA "+EE$
7602 CC$(12)="COMMAND":CC$(13)="NEXT":CC$(14)=ZA$
7603 CC$(3)="BCC 23":CC$(4)="BNE 18":CC$(7)="BCC 13":CC$(8)="BNE 8":CC$(11)="BCC 3"

7605 SS$=SG$:GOSUB 400:IF T=1 THEN GOTO 7610
7606 HH$=STR$(IX):II$=STR$(IY):JJ$=STR$(IZ)
7607 CC$(2)="CMP "+JJ$:CC$(6)="CMP "+II$:CC$(10)="CMP "+HH$
7608 A=14:LP=LP+1:GOTO 300

7610 GG=INT(V/(256*256)):H=V-(GG*256*256):CC$(2)="CMP #"+STR$(GG):H=V-(GG*256*256):GOSUB 700
7611 CC$(10)="CMP #"+STR$(HX(2)):CC$(6)="CMP #"+STR$(HX(1))

7615 CC$(3)="BCC 21":CC$(4)="BNE 16":CC$(7)="BCC 12":CC$(8)="BNE 7":CC$(11)="BCC 3":GOTO 7608


REM-----------------IF 24BIT >
 7700 SS$ = SG$: GOSUB 400: IF T = 1 THEN X = X: GOSUB 7710:SS$ = SF$: GOSUB 400: GOSUB 7702:GOTO 7715
 7701  GOSUB 7702: GOSUB 7709:GOTO 7608
 7702 EE$ =  STR$ (IX):FF$ =  STR$ (IY):GG$ =  STR$ (IZ)
 7703 CC$(2) = "CMP " + GG$:CC$(6) = "CMP " + FF$:CC$(10) = "CMP " + EE$
 7704 CC$(12) = "COMMAND":CC$(13) = "NEXT":CC$(14) = ZA$
 7705 CC$(3) = "BCC 20":CC$(4) = "BNE 21":CC$(7) = "BCC 10":CC$(8) = "BNE 11":CC$(11) = "BCS 3"
 7706 SS$ = SF$: GOSUB 400
 7707 HH$ =  STR$ (IX):II$ =  STR$ (IY):JJ$ =  STR$ (IZ): RETURN 
 7709 CC$(1) = "LDA " + JJ$:CC$(5) = "LDA " + II$:CC$(9) = "LDA " + HH$: RETURN 
 7710 GG =  INT (V / (256 * 256)):H = V - (GG * 256 * 256):CC$(1) = "LDA #" +  STR$ (GG):H = V - (GG * 256 * 256): GOSUB 700
 7711 CC$(5) = "LDA #" +  STR$ (HX(1)):CC$(9) = "LDA #" +  STR$ (HX(2)): RETURN

 7715 CC$(3) = "BCC 18":CC$(4) = "BNE 19":CC$(7) = "BCC 9":CC$(8) = "BNE 10":CC$(11) = "BCS 3"
 7716 GOTO 7608


REM----------------EQUALS DIRECTOR
9000 EC$=A$:HTAB 35:PRINT EA$;" = ";EC$:GOSUB 9990
9001 ON A GOTO 5010,3310,7100


REM---------------ADDITION DIRECTOR
9010 EC$=A$:GOSUB 1100:ED$=A$:HTAB 35:PRINT EA$;" = ";EC$;" + ";ED$:GOSUB 9990
9011 IF EA$=EC$ GOTO 9015
9012 IF EA$=ED$ GOTO 9015
9013 ON A GOTO 5020,3320,7200
9015 IF EC$="1" GOTO 9019
9016 IF ED$="1" GOTO 9019
9017 GOTO 9013
9019 SX$=EA$:ON A GOTO 5130,3440,7440

REM---------------SUBTRACTION DIRECTOR
9020 EC$=A$:GOSUB 1100:ED$=A$:HTAB 35:PRINT EA$;" = ";EC$;" - ";ED$:GOSUB 9990
9021 IF EA$=EC$ GOTO 9025
9022 IF EA$=ED$ GOTO 9025
9023 ON A GOTO 5030,3340,7300
9025 IF EC$="1" GOTO 9029
9026 IF ED$="1" GOTO 9029
9027 GOTO 9023
9029 SX$=EA$:ON A GOTO 5140,3450,7450


REM---------------DIVISION DIRECTOR
9040 EC$=A$:GOSUB 1100:ED$=A$:HTAB 35:PRINT EA$;" = ";EC$;" / ";ED$
9041 GOSUB 9995
9042 IF EA$=EC$ GOTO 9045
9043 IF EA$=ED$ GOTO 9045
9044 ON A GOTO 5060,3380
9045 IF EC$="2" GOTO 9049
9046 IF ED$="2" GOTO 9049
9047 GOTO 9044
9049 SX$=EA$:ON A GOTO 5110,3410,7410


REM-------------IF DIRECTOR
9050 GOSUB 1100:EA$=A$:EB=PEEK(LP):EB$=STR$(EB):GOSUB 1100:EC$=A$
9051 IF EB=208 THEN EB=1:EB$="="
9052 IF EB=207 THEN EB=2:EB$=">"
9053 IF EB=209 THEN EB=3:EB$="<"
9054 HTAB 35:PRINT "IF ";EA$;" ";EB$;" ";EC$;" THEN": GOSUB 9990
9055 ON A GOTO 5200,3200,7500


REM---------------MULTIPLICATION DIRECTOR
9060 EC$=A$:GOSUB 1100:ED$=A$:HTAB 35:PRINT EA$;" = ";EC$;" * ";ED$
9061 GOSUB 9995
9062 IF EA$=EC$ GOTO 9065
9063 IF EA$=ED$ GOTO 9065
9064 ON A GOTO 5040,3360
9065 IF EC$="2" GOTO 9070
9066 IF ED$="2" GOTO 9070
9067 IF EC$="10" GOTO 9071
9068 IF ED$="10" GOTO 9071
9069 GOTO 9064
9070 SX$=EA$:ON A GOTO 5120,3420,7420
9071 SX$=EA$:IF A=2 GOTO 3430
9072 GOTO 9064


REM ------BIT DEPTH SELECTOR
9990 HTAB 35:PRINT "1- 8BIT / 2- 16BIT / 3- 24BIT":POKE -16368,0
9991 A=PEEK(-16384):IF A<128 GOTO 9991
9992 POKE -16368,0:A=A-176
9993 IF A<1 OR A>3 GOTO 9990
9994 RETURN
9995 HTAB 35:PRINT "1- 8BIT / 2- 16BIT":POKE -16368,0:GOTO 9991


REM=================================================

FOR X=35000 TO LP+10:PRINT PEEK(X);" ";:NEXT
